Play PLS stream files in Windows Media Player (no need to install Winamp)

Winamp is a really very nice clean software. No Arguments there. But, I don't want to install it on my business laptop. I want to here all shoutcast streams and other radio stations in my Windows Media Player. So I made a little script myself (and I blogged it HERE).

Follow the steps to play PLS file in Windows Media Player:

1. Copy and Paste the following script into Notepad and save it as "PlayPLS.VBS". NOTE: While saving the script from Notepad, You NEED to type the vbscriptname.vbs in QUTOES. e.g., "PlayPLS.vbs". Otherwise it will save as PlayPLS.vbs.txt

'*****************************************************************************
'*****************************************************************************
'*********                       PlayPLS.vbs                        **********
'********* Parameters: PLS file name                                **********
'*********                                                          **********
'********* This script plays .PLS files in Windows Media Player     **********
'*********                                                          **********
'********* Usage: PlayPLS.vbs Sample.PLS                            **********
'*********                                                          **********
'********* Written By: Anand Venkatachalapathy                      **********
'*****************************************************************************
'*****************************************************************************

Set WshShell = WScript.CreateObject("WScript.Shell")
Set oArg = WScript.Arguments
Const ForReading = 1, ForWriting = 2, ForAppending = 8
Dim fso, f
Set fso = CreateObject("Scripting.FileSystemObject")

If oArg.Count = 0 Then
    WshShell.Popup "Invalid Arguments...Please provide the PLS file name.", _
7, "Play PLS in WMP",0
    WScript.Quit
End If

sPLSFileName = oArg(0)
Set f = fso.OpenTextFile(sPLSFileName, ForReading)

Do While NOT f.AtEndOfStream
    sText =  f.ReadLine
    If InStr(UCase(sText),"FILE") > 0 Then
        sURLText =  Split(sText,"=")
        sURL = """" & sURLText(1) & """"
        sCmd = "WMPlayer " & sURL
        WshShell.Run sCmd
        Exit Do
    End If
Loop

f.close
Set fso = Nothing
Set oArg = Nothing
Set WshShell = Nothing

2. Copy and Paste the following text into Notepad and save it as PlayPLS.cmd. NOTE: Use the "double quotes" when saving the name in Notepad.

C:\PathOfTheFolder\PlayPLS.vbs %1

3. Open your favorite radio station (mine is http://www.shoutcast.com), right click on PLS file link (or PLAY button) and save it on your desktop.

4. Open the file properties of PLS file (by right clicking on the PLS on the desktop and select properties), Click "Change" button next to the "Opens With:" text. Select the PlayPLS.cmd file by browsing to the corresponding folder and select the cmd file.

5. You are done. Go to your favorite radio web site again and click on "Play" Link. See it open in Windows Media Player.